Code zu Internet und Netzwerk in .NET

Public Function LoadTextFile(ByVal Url As String) As String
    Dim Request As WebRequest = WebRequest.Create(Url)
    Dim Response As WebResponse = Request.GetResponse()
    Dim Reader As New StreamReader(Response.GetResponseStream())
    LoadTextFile = Reader.ReadToEnd()
    Reader.Close()
    Response.Close()
    Return LoadTextFile
End Function

Console.WriteLine("IP-Adresse(n) des Computers:")
For Each Address As IPAddress In Dns.Resolve(SystemInformation.ComputerName).AddressList
    Console.WriteLine(Address.ToString())
Next Address

' Requires a reference to "Microsoft Internet Controls" ("SHDocVw.dll").
Public Function ReplaceInternetExplorerUrl( _
    ByVal OldUrl As String, _
    ByVal NewUrl As String, _
    Optional ByVal FirstInstanceOnly As Boolean = False _
) As Integer
    Dim ReplacedCount As Integer
    For Each IE As InternetExplorer In New ShellWindows()
        If IE.LocationURL = OldUrl Then
            IE.Navigate(NewUrl)
            ReplacedCount += 1
            If FirstInstanceOnly Then
                Exit For
            End If
        End If
    Next IE
    Return ReplacedCount
End Function

Public Class InternetDialer
    Public Declare Function InternetAutodial Lib "wininet.dll" ( _
        ByVal dwFlags As Int32, _
        ByVal hwndParent As IntPtr _
    ) As Boolean

    Private Const INTERNET_AUTODIAL_FORCE_ONLINE As Int32 = &H1
    Private Const INTERNET_AUTODIAL_FORCE_UNATTENDED As Int32 = &H2
    Private Const INTERNET_AUTODIAL_FAILIFSECURITYCHECK As Int32 = &H4
    Private Const INTERNET_AUTODIAL_OVERRIDE_NET_PRESENT As Int32 = &H8

    Private Declare Function InternetAutodialHangup Lib "wininet.dll" ( _
        ByVal dwReserved As Int32 _
    ) As Boolean

    Public Enum AutoDialOptions
        ForceOnline = INTERNET_AUTODIAL_FORCE_ONLINE
        ForceUnattended = INTERNET_AUTODIAL_FORCE_UNATTENDED
        FailIfSecurityCheck = INTERNET_AUTODIAL_FAILIFSECURITYCHECK
        OverrideNetPresent = INTERNET_AUTODIAL_OVERRIDE_NET_PRESENT
    End Enum

    Public Shared Sub Dialup(ByVal Options As AutoDialOptions)
        Dialup(Options, IntPtr.Zero)
    End Sub

    Public Shared Sub Dialup( _
        ByVal Options As AutoDialOptions, _
        ByVal Parent As Control _
    )
        Dialup(Options, Parent.Handle)
    End Sub

    Public Shared Sub Dialup( _
        ByVal Options As AutoDialOptions, _
        ByVal hwndParent As IntPtr _
    )
        If Not InternetAutodial(Options, hwndParent) Then
            Throw _
                New ApplicationException( _
                    "Error dialling the default internet connection." _
                )
        End If
    End Sub

    Public Shared Sub Hangup()
        If Not InternetAutodialHangup(0) Then
            Throw _
                New ApplicationException( _
                    "Error disconnecting internet connection." _
                )
        End If
    End Sub
End Class

Dim Client As New WebClient()
Client.Headers.Add("Content-Type", "application/x-www-form-urlencoded")
Client.UploadData( _
    "https://www.google.com/adsense/login.do", _
    "POST", _
    Encoding.UTF8.GetBytes("username=<user name>&password=<password>") _
)
Client.Headers.Clear()
Client.Headers.Add("Cookie", Client.ResponseHeaders("Set-Cookie"))
Dim Data() As Byte = _
    Client.DownloadData("https://www.google.com/adsense/report/overview")
Client.Dispose()
MsgBox(Encoding.UTF8.GetString(Data))

Dim Request As HttpWebRequest = _
    DirectCast( _
        HttpWebRequest.Create("https://www.google.com/adsense/login.do"), _
        HttpWebRequest _
    )
Dim Cookies As New CookieContainer()
With Request
    .CookieContainer = Cookies
    .Method = "POST"
    .ContentType = "application/x-www-form-urlencoded"
End With
Dim Writer As New StreamWriter(Request.GetRequestStream())
Writer.Write("username=<user name>&password=<password>")
Writer.Close()
Request.GetResponse().Close()
Request = _
    DirectCast( _
        WebRequest.Create("https://www.google.com/adsense/report/overview"), _
        HttpWebRequest _
    )
Request.CookieContainer = Cookies
Dim Reader As New StreamReader(Request.GetResponse().GetResponseStream())
MsgBox(Reader.ReadToEnd())
Reader.Close()

Imports Microsoft.Win32
Imports System.IO
Imports System.Net

⋮

Public Function DownloadFile( _
    ByVal Uri As String, _
    ByVal DestinationDirectory As String, _
    Optional ByVal PreferContentDisposition As Boolean = False _
) As String
    Dim Request As HttpWebRequest = _
        DirectCast(WebRequest.Create(Uri), HttpWebRequest)
    Dim Response As WebResponse = Request.GetResponse()
    Dim ResponseStream As Stream = Response.GetResponseStream()
    Dim FileName As String = Nothing
    If PreferContentDisposition Then
        Dim ContentDisposition As String = _
            Response.Headers("Content-Disposition")
        If ContentDisposition IsNot Nothing Then
            Dim Parts() As String = Split(ContentDisposition, ";")
            If Parts.Length > 0 Then
                For i As Integer = 1 To Parts.Length
                    Dim DispositionParam As String = Parts(i)
                    Dim ParamParts() As String = _
                        Split(DispositionParam, "=")
                    Dim Param As String = ParamParts(0)
                    Dim ParamValue As String = ParamParts(1)
                    If Param Is "filename" Then
                        FileName = Path.GetFileName(ParamValue)
                        Exit For
                    End If
                Next i
            End If
        End If
    End If
    If FileName Is Nothing Then
        Dim FileUri As New Uri(Uri)
        FileName = _
            Replace( _
                FileUri.Segments(FileUri.Segments.Length - 1), _
                "/", _
                String.Empty _
            )
        FileName = Path.GetFileNameWithoutExtension(FileName)
        If Len(FileName) = 0 Then
            FileName = Replace(FileUri.Host, ".", "_")
        End If
        Dim Key As RegistryKey = _
            Registry.ClassesRoot.OpenSubKey( _
                "MIME\Database\Content Type\" & Response.ContentType _
            )
        If Key IsNot Nothing Then
            Dim Extension As String = _
                DirectCast(Key.GetValue("Extension"), String)
            If Extension IsNot Nothing Then
                FileName = FileName & Extension
            End If
        End If
    End If
    FileName = Path.Combine(DestinationDirectory, FileName)

    ' Download data and write file.
    Using Reader As New BinaryReader(ResponseStream)
        Using Writer As New BinaryWriter( _
            New FileStream(FileName, FileMode.CreateNew) _
        )

            ' Read blocks of 4 KB.
            Const BlockSize As Integer = 4096
            Dim Buffer() As Byte
            Do
                Buffer = Reader.ReadBytes(BlockSize)
                Writer.Write(Buffer)
            Loop While Buffer.Length > 0
        End Using
    End Using
    Response.Close()
    Return FileName
End Function